m4_define(_HEADER_DIVERT,m4_defn(`m4_divert'))
m4_define(`m4_divert',`')
m4_define(`__PAGEURL',`true')

m4_dnl Add a word to the index.
m4_define(`_INDEX',`_HEADER_DIVERT(1)m4_ifdef(``__POINT'',``__POINT'',``__PAGEURL'')	m4_ifdef(``__POINTNAME'',``__POINTNAME'',``__PAGETITLE'')	``$1'',``$2'',``$3'',``$4'',``$5''
		    _HEADER_DIVERT(-1)')
m4_dnl Add the word to the index, and insert it inline at current point.
m4_define(`_IX',`_INDEX(``$1'')$1')
m4_dnl Add a lowercase word to the index, and insert it inline at current point.
m4_dnl m4_define(`_IXL',`_INDEX(``$1'')m4_translit($1,A-Z,a-z)')

m4_dnl Add a "see" entry to $1 from an index entry.
m4_define(`_IXSEE',`_HEADER_DIVERT(1)SEE	``$1''	``$2'',``$3'',``$4'',``$5'',``$6''
		    _HEADER_DIVERT(-1)')
m4_dnl Add a "see also" entry to $1 from an index entry.
m4_define(`_IXSEEALSO',`_HEADER_DIVERT(1)ALSO	``$1''	``$2'',``$3'',``$4'',``$5'',``$6''
		    _HEADER_DIVERT(-1)')

m4_dnl Add an index entry to a specified document.
m4_define(`_IXLINK',`_HEADER_DIVERT(1)SITE_URL/``$1''	``$2''	``$3'',``$4'',``$5'',``$6'',``$7''
		    _HEADER_DIVERT(-1)')

m4_define(`__INDEXING', `true')
m4_define(`__EXTRACTING', `true')
_HEADER_DIVERT(-1)
m4_include(FILE_SOURCE)